#! /bin/csh -f
#
#       @(#)options 1.5 10/19/87 Copyright 1985 Sun Micro
#
#	List some sysdiag options.
#
onintr finit

if ("$argv" != sd) echo ' '
if ($?SYSDIAG_VERSION) then
  echo 'sysdiag version '$SYSDIAG_VERSION' '
endif
if (-e logtimes && "$argv" != sd) then
#  echo ' '
#  awk '/start/ {print "Test started on " $4, $5, $6, $7}' logtimes
#  echo ' '
  awk '/start/ {x = sprintf("Test was started on %s, %s %s %s", $4, $5, $6, $7)} END {print x}' logtimes
endif

if ($?SHOEBOX_TEST)      echo 'Shoebox test is enabled'
if ($?RUN_ON_ERROR)      echo 'Run on error is enabled'
if ($?SINGLE_PASS)       echo 'Single pass  is enabled'
if ($?LOG_PASS_MSG)      echo 'Log pass msg is enabled'
if ($?SD_LOAD_TEST)      echo 'Load test    is enabled'
if ($?NO_TAPE_SLEEP)     echo 'Tape sleep  is disabled'
if ($?NO_CLEAN_HEADS)    echo 'Tape clean  is disabled'
if ($?NO_TAPE_RETENSION) echo 'Tape retension disabled'
if ("$argv" != sd) echo ' '

finit: 

if ("$argv" != sd && $TERM == sun && $?WINDOW_PARENT) then
  echo '**********************************************'
  echo '*  When ready to end testing,  enter a "^C"  *'
  echo '*  in each test window. When the tests have  *'
  echo '*  ended  (a command prompt in each window)  *'
  echo '*  select exit from  the  root  window menu. *'
  echo '**********************************************'
endif

if ("$argv" != sd && (!($?NEW_SHELL)) && $TERM == sun && $?WINDOW_PARENT) then
  setenv NEW_SHELL no
  exec /bin/csh
endif
